Cómo desarrollar aplicación de servicio en Windows con VB.Net

Explicamos paso a paso en este tutorial cómo realizar un servicio de Windows mediante el lenguaje de programación Microsoft Visual Basic .Net de Microsoft Visual Studio .Net. Mostramos cómo desarrollar una aplicación especial: un servicio de Windows. Dicha aplicación se integrará perfectamente en los servicios de Microsoft Windows 7 (o cualquier otro sistema operativo de Microsoft).

Anexo.

Los servicios de Windows, definición, cómo se configuran, cómo consultar su estado

Un servicio de Windows es una aplicación normal con algunas pequeñas variaciones. Es un programa que es iniciado por el sistema operativo en su arranque (si así ha sido configurado). El usuario, en una situación normal, no los inicia ni los detiene, es el sistema operativo el que realiza estas tareas, normalmente de forma automática.

Un servicio de Windows es una aplicación que se ejecuta en segundo plano (background), en situaciones normales un servicio no interactúa con el usuario, no suelen mostrarse ventanas ni mensajes que el usuario pueda ver. Suelen ser aplicaciones que realizan tareas y procesos que no requieren de la intervención del usuario.

Un servicio de Windows se puede iniciar o detener desde la ventana de Servicios de Windows. Para el caso de Microsoft Windows 7, desde el botón "Iniciar" - "Panel de control" - "Herramientas administrativas" - "Servicios". En esta ventana podremos ver todos los servicios instalados en el sistema operativo y su estado (iniciados, detenidos o pausados). Pulsando con el botón derecho del ratón sobre uno de ellos y seleccionando "Propiedades":

AjpdSoft Los servicios de Windows, definición, cómo se configuran, cómo se ven

podremos ver las propiedades y configuración para el servicio actual. En la pestaña "General":

Nombre de servicio: nombre con el que se identifica el servicio para tareas internas (iniciarlo o detenerlo desde la línea de comandos, etc.).
Nombre para mostrar: nombre que aparece en la columna "Nombre" de la ventana de servicios.
Descripción: descripción larga de lo que hace el servicio o la empresa que lo ha desarrollado.
Ruta de acceso al ejecutable: carpeta y fichero ejecutable (aplicación) del servicio.
Tipo de inicio: modo en el que arrancará el servicio: Automático (inicio retrasado), Automático, Manual ó Deshabilitado.
Estado del servicio: estado actual del servicio: Iniciado, Detenido, Pausado.
Con los botones "Iniciar", "Detener", "Pausar", "Reanudar" se podrá cambiar el estado del servicio.

En la pestaña "Iniciar sesión": desde esta pestaña podremos configurar las opciones de seguridad, indicando con qué usuario del equipo o del dominio (si el equipo pertenece a un dominio Windows). Si el servicio requiere de interactuación con el usuario (aunque no es lo habitual) podremos marcar la opción "Permitir que el servicio interactúe con el escritorio":

En la pestaña "Recuperación" podremos configurar las acciones a realizar en caso de que se produzca algún error en la ejecución del servicio: qué hacer si se produce el primer error, el segundo, si se producen más errores:

En la pestaña "Dependencias" se mostrará si el inicio de un servicio depende de que otros servicios estén iniciados. De ser así, antes de iniciar el servicio los servicios de los que depende deben estar iniciados. También ocurre a la inversa, si otros servicios dependen de éste y lo detenemos, también se detendrán los servicios que dependen de éste:

Normalmente, los servicios iniciados suelen verse en el Administrador de tareas de Windows, desde la pestaña "Procesos":

Nota: en el ejemplo que os estamos mostrando, el servicio se llama "Apache2.2" y como se puede observar, el proceso se llama "httpd.exe", esto es porque el servicio "Apache2.2" en realidad ejecuta el fichero "httpd.exe" (como se puede observar más atrás en "Ruta de acceso al ejecutable").

Hay que tener en cuenta, si decidimos iniciar, detener o cambiar el modo de inicio de algunos servicios (incluso si los deshabilitamos para impedir su arranque), que algunos servicios son necesarios para el correcto funcionamiento del sistema operativo, por lo que si cambiamos su estado puede que éste deje de funcionar correctamente. Por lo que es recomendable no modificar el estado y tipo de inicio de estos servicios.

En el caso de que nuestro equipo vaya "lento" y pueda ser debido a que tenemos muchos servicios de aplicaciones innecesarias en ejecución, podremos usar la herramienta "msconfig" (Configuración del sistema), desde el botón "Iniciar" - escribiendo "msconfig":

En la pestaña "Servicios" de "Configuración del sistema" podremos deshabilitar los servicios que consideremos que no son necesarios. Marcando la opción "Ocultar todos los servicios de Microsoft" no se mostrarán los servicios del sistema operativo, por lo que evitaremos cometer posibles errores. Hay que tener en cuenta que los servicios que desmarquemos en esta ventana cambiarán el tipo de inicio a "Deshabilitado", por lo que no podrán ejecutarse ni tan siquiera de forma manual hasta que no volvamos a cambiar el tipo de inicio a Manual o a Automático. Por ello hay que proceder con precaución o algunas aplicaciones dejarán de funcionar:

Desarrollar un servicio de Windows con VB.Net Visual Basic .Net

Propósito del servicio Windows que desarrollaremos

A continuación vamos a explicar paso a paso cómo desarrollar un servicio para Windows. Vamos a realizar una aplicación que será y se integrará como un servicio de Windows.

Vamos a desarrollar un servicio de ejemplo que permita cifrar todos los archivos contenidos en una carpeta especificada del equipo. Cada fichero que el usuario copie en dicha carpeta será automáticamente cifrado por nuestro servicio. Utilizaremos un algoritmo de cifrado sencillo y el componente FileSystemWatcher para recibir una notificación cada vez que se cree un nuevo archivo en una determinada carpeta.

A continuación vamos a explicar cómo hacer un servicio con Microsoft Visual Basic .Net 2010 (válido para otras versiones) que, cada vez que el usuario cree un fichero en una carpeta determinada. El servicio se iniciará de forma automática usando FileSystemWatcher.

Este es un ejemplo cualquiera, los servicios se pueden utilizar para cualquier tarea que estimemos oportuna, con un poco de lógica, claro, no se debe confundir el uso específico de un sevicio con el de una aplicación de escritorio. El servicio es una simple tarea que dotará de una utilidad extra a otra aplicación o para realizar tareas repetitivas y automáticas, que no requiere de intervención del usuario y que se debe ejecutar cada cierto tiempo durante todo el día o cuando se produzca un cierto "evento" como es el caso del ejemplo de este artículo.

Desarrollar o implementar un servicio de Windows con Visual Basic .Net

Abriremos Microsoft Visual Basic .Net, pulsaremos en "Archivo" - "Nuevo proyecto":

Seleccionaremos "Visual Basic" - "Windows" en la parte izquierda de "Plantillas instaladas", en la parte derecha seleccionaremos "Servicio de Windows". Introduciremos en nombre el identificador del proyecto, por ejemplo "AjpdSoftServicioEncriptarCarpeta" y pulsaremos "Aceptar":

Nos mostrará la superficie de diseño para el fichero "Service1.vb" que será el principal de nuestra aplicación de servicio de Windows:

Pulsando en el "Explorador de soluciones" podremos ver los ficheros que se han creado, renombraremos el fichero "Service1.vb" por el nombre que queramos, por ejemplo "EncriptarCarpeta.vb":

Agregaremos ahora el componente que nos permitirá saber cuándo el usuario ha creado un nuevo fichero en la carpeta especificada. Este componente será el que "active" nuestra aplicación para que encripte el nuevo fichero. Para agregar este componente pulsaremos en el Cuadro de herramientas, en "Componentes" - "FileSystemWatcher" (realiza el seguimiento de las notificaciones de cambio del sistema de archivos y desencadena eventos cuando cambia un directorio o archivo):

El componente FileSystemWatcher quedará agregado:

Estableceremos ahora las propiedades del servicio que estamos desarrollando. Para ello pulsaremos con el botón derecho sobre la superficie de diseño y seleccionaremos "Propiedades":

Las propiedades disponibles para nuestra aplicación servicio de Windows son:

Name: nombre del servicio (System.ServiceProcess.ServiceBase) para uso en el código de nuestra aplicación.
AutoLog: si establecemos esta propiedad a True, el servicio escribirá entradas de forma automática en el registro de sucesos "Aplicación" de Windows, en las siguientes situaciones: cuando el servicio se inicia y se detiene con éxito, cuando se detiene de forma temporal (pausa) y se reaunda con éxito y, finalmente, cuando algún comando no se ejecuta correctamente. Los mensajes enviados al registro de sucesos de Windows son más bien genéricos, del tipo "El servicio se ha iniciado con éxito" y no tendrá control sobre su contenido, pero resultan adecuados en la mayoría de los casos y de gran utilidad, especialmente durante la fase de depuración de la aplicación.
CanHandlePowerEvent: indica si el servicio puede controlar notificaciones de los cambios de estado de la alimentación del equipo.
CanHandleSessionChangeEvent: indica si el servicio puede controlar eventos de cambio de sesión recibidos de una sesión de Terminal Server.
CanPauseAndContinue: indica si se puede pausar y reanudar el servicio.
CanShutdown: indica si se debe informar al servicio de que el sistema se está cerrando.
CanStop: indica si puede detenerse el servicio una vez se ha iniciado.
ExitCode: obtiene o establece el código de salida para el servicio.
Language: lenguaje de la aplicación de servicio.
Localizable: determina si se va a generar código traducible para este objeto.
ServiceName: nombre que identificará el servicio en el sistema Windows. Será el nombre que se establezca para el servicio en Windows.

Indicamos también a continuación las propiedades para el componente FileSystemWatcher anteriormente agregado:

Name: nombre identificativo para el componente para uso en el código, por ejemplo "cambioFicheroCarpeta".
EnableRaisingEvents: indica si el componente está habilitado, lo pondremosa False para que el componente no provoque sucesos antes de que se inicie el servicio.
Filter: cadena de filtro utilizada para determinar qué archivos se supervisan en un directorio.
GenerateMember: indica si se generará una variable miembro para este componente.
IncludeSubdirectories: indica si se deben supervisar los subdirectorios de la ruta de acceso especificada.
Modifiers: indica el nivel de visibilidad del objeto.
NotifyFilter: establece el tipo de cambios que se van a inspeccionar.
Path: establece la ruta de acceso del directorio que se va a inspeccionar.

El servicio leerá la carpeta que usará para comprimir los archivos de un fichero de configuración INI. De esta forma el usuario podrá indicar qué carpeta quiere usar. Para ello añadiremos una clase a nuestro proyecto VB.Net que nos permitirá leer valores de configuración de ficheros INI. Para añadir esta clase pulsaremos en el "Explorador de soluciones", pulsaremos con el botón derecho sobre el proyecto y seleccionaremos "Agregar" - "Clase":

Introduciremos un nombre para la clase, por ejemplo "LeerEscribirFicherosINI.vb":

Copiaremos y pegaremos el código de este enlace (contenido de la clase para trabajar con ficheros INI) en el fichero de clase creado "LeerEscribirFicherosINI": Funciones para leer y escribir en ficheros INI VB.Net:

Añadiremos ahora el código VB.Net necesario para activar el componente FileSystemWatcher cuando se inicie el servicio, en el evento "OnStart" del fichero "EncriptarCarpeta.vb":

    Protected Overrides Sub OnStart(ByVal args() As String)
        Dim carpetaCifrar As String

        'Leemos la carpeta a cifrar del fichero INI de configuración
        Dim objFicherosINI As New LeerEscribirFicherosINI(
              System.IO.Path.Combine(System.AppDomain.CurrentDomain.BaseDirectory,
                  "configuracion.ini"))
        carpetaCifrar = objFicherosINI.GetString("Configuración", "Carpeta",
              System.AppDomain.CurrentDomain.BaseDirectory)

        'Comprobamos que el directorio a encriptar existe
        'Si no existe lo creamos
        If Not System.IO.Directory.Exists(carpetaCifrar) Then
            System.IO.Directory.CreateDirectory(carpetaCifrar)
        End If

        'Activamos la recepción de sucesos de archivos
        cambioFicheroCarpeta.Path = carpetaCifrar
        cambioFicheroCarpeta.EnableRaisingEvents = True
    End Sub

Añadiremos ahora el código VB.Net necesario para desactivar el componente FileSystemWatcher cuando se detenga el servicio, en el evento "OnStop" del fichero "EncriptarCarpeta.vb":

    Protected Overrides Sub OnStop()
        'Detenemos la recepción de sucesos de archivos
        cambioFicheroCarpeta.EnableRaisingEvents = False
    End Sub

Introduciremos ahora el código VB.Net necesario para cifrar los ficheros que el usuario vaya creando o copiando a la carpeta establecida en el fichero de configuración INI. Por un lado declararemos una variable para establecer la contraseña de cifrado y la extensión de los ficheros temporales que se crearán para el cifrado:

Public Class EncriptarCarpeta

    Dim clavesCifrado() As Byte = {234, 125, 22, 6, 54, 45, 254}
    Dim extensionFicherosTMP As String = ".###"

Crearemos los procedimientos necesarios para el cifrado de los ficheros:

    Private Sub encritarFicheros(ByVal nombreFichero As String, 
              ByVal clavesCifrado() As Byte)
        'tamaño de cada bloque de entrada, 
        'el tamaño para descrifrar deberá ser igual
        Const tamanoBloque = 8192
        'nombre del fichero temporal que se creará para el cifrado
        Dim ficheroTemporal As String = nombreFichero & extensionFicherosTMP
        'abrimos el archivo origen como una secuencia binaria de entrada
        Dim entradaStr As New System.IO.FileStream(nombreFichero, IO.FileMode.Open)
        'abrimos el archivo temporal de salida como una secuencia binaria de entrada
        Dim salidaStr As New System.IO.FileStream(ficheroTemporal, IO.FileMode.Create)
        'determinar el número de bytes que se desean leer
        Dim tamanoBytes As Long = entradaStr.Length
        'preparar un búfer de entrada
        Dim buffer(tamanoBloque - 1) As Byte
        'mientras que haya bytes que leer
        Do While tamanoBytes > 0
            'lectura máxima de 8kb por bloque
            Dim bytesLeer As Long = Math.Min(tamanoBloque, tamanoBytes)
            'leer dentro del búfer de entrada
            entradaStr.Read(buffer, 0, bytesLeer)
            'cifrar este búfer
            encritarArray(buffer, clavesCifrado)
            'enviar la salida a un archivo temporal
            salidaStr.Write(buffer, 0, bytesLeer)
            tamanoBytes -= bytesLeer
        Loop
        'cerrar las dos secuencias
        entradaStr.Close()
        salidaStr.Close()
        'eliminar el archivo de origen
        System.IO.File.Delete(nombreFichero)
        'renombrar el archivo temporal como el original
        System.IO.File.Move(ficheroTemporal, nombreFichero)
    End Sub

    'Cifrar con xor una matriz de bytes
    Sub encritarArray(ByVal buffer() As Byte, ByVal pwBytes() As Byte)
        'índice que apunta al búfer
        Dim indice As Integer
        'índice que apunta a la matriz de contraseñas
        Dim i As Integer
        'valor máximo de i
        Dim maximo As Integer = pwBytes.Length
        For indice = 0 To buffer.Length - 1
            'hacer un XOR de cada elemento contenido en el búfer con
            'el correspondiente elemento de contraseña
            buffer(indice) = buffer(indice) Xor pwBytes(i)
            'comprobar que el índice corresponde siempre al rango válido
            i = (i + 1) Mod maximo
        Next
    End Sub

En el evento OnCreated del FileSystemWatcher añadiremos el siguiente código VB.Net:

    Private Sub cambioFicheroCarpeta_Created(sender As System.Object, _
            e As System.IO.FileSystemEventArgs) _
            Handles cambioFicheroCarpeta.Created
        Dim carpetaCifrar As String

        'Leemos la carpeta a cifrar del fichero INI de configuración
        Dim objFicherosINI As New LeerEscribirFicherosINI(
              System.IO.Path.Combine(System.AppDomain.CurrentDomain.BaseDirectory,
                  "configuracion.ini"))
        carpetaCifrar = objFicherosINI.GetString("Configuración", "Carpeta",
              System.AppDomain.CurrentDomain.BaseDirectory)
        If System.IO.Path.GetExtension(carpetaCifrar) <> extensionFicherosTMP Then
            encritarFicheros(carpetaCifrar, clavesCifrado)
        End If
    End Sub

Agregar instalador a proyecto VB.Net ServiceInstaller y ServiceProcessInstaller

Los servicios de Windows no se pueden iniciar como una aplicación normal. En primer lugar, para iniciar un servicio de Windows, deberemos instalarlo en el equipo en el que queramos ejecutarlo y, a continuación, podremos iniciarlo mediante el complemento Servicios (services.msc) o bien desde la línea de comandos usando NET START.

En el caso de Microsoft Visual Basic .Net, el primer paso para poder instalar el servicio es agregar una clase instaladora. Esta clase puede ser instalada o bien usando la herramienta automática de la que dispone Microsoft Visual Studio .Net o bien creando manualmente la clase instaladora mediante código.

El primer método es el más sencillo y se adapta a casi todas las situaciones normales de un servicio. Para usarlo accederemos a la ventana de diseño de nuestra aplicación de servicio (EncriptarCarpeta.vb [Diseño]), en esta pestaña pulsaremos con el botón derecho del ratón en cualquier parte donde no haya elementos, nos mostrará un mensaje emergente, seleccionaremos "Agregar instalador":

Agregar instalador a proyecto VB.Net ServiceInstaller y ServiceProcessInstaller

Visual Basic .Net añadirá un nuevo componente a la aplicación de servicio llamado ProjectInstaller.vb, en este nuevo componente habrá añadido dos objetos adicionales: ServiceProcessInstaller1 y ServiceInstaller1. Pulsando con el botón derecho del ratón sobre ServiceInstaller1 y seleccionando "Propiedades" podremos establecer las propiedades para el servicio que se instalará, las más importantes:

ServiceName: esta propiedad debe coincidir con la propiedad ServiceName de la clase servicio que hemos configurado inicialmente, en nuestro caso AjpdSoftEncriptarFicheros.
DisplayName: cadena de texto descriptiva del servicio, por ejemplo indicando lo que hace: "Encripta los ficheros de la carpeta indicada en el fichero de configuración". Este texto aparecerá en el programa complementario MMC denominado Servicios (services.msc).
StartType: tipo de inicio del servicio, las posibilidades son: automático, manual o deshabilitado. En nuestro caso seleccionaremos "Automatic" para que el servicio se inicie de forma automática cada vez que arranquemos el equipo.
ServicesDependedOn: si nuestro servicio depende de otros servicios para poder ser iniciado, es decir, si para iniciar nuestro servicio debe haber otros iniciados los podremos indicar aquí.

Para configurar el contexto de seguridad del servicio pulsaremos con el botón derecho del ratón sobre "ServiceProcessInstaller1", seleccionaremos "Propiedades". Desde esta ventana de propiedades podremos indicar el tipo de cuenta en "Account" con las posibilidades:

LocalService: cuenta que actúa como usuario sin privilegios en el equipo local y presenta credenciales anónimas a cualquier servidor remoto.
NetworkService: cuenta que proporciona amplis privilegios locales y presenta credenciales del equipo a cualquier servidor remoto.
LocalSystem: una cuenta, utilizada por el administrador de control de servicio, que tiene amplios privilegios en el equipo local y funciona como un equipo de la red.
User: cuenta definida por un usuario específico en la red. Si se especifica User para el miembro ServiceProcessInstaller.Account, el sistema pide un nombre de usuario y una contraseña al instalar el servicio, a menos que se establezcan valores para las propiedades Username y Password de la instancia de ServiceProcessInstaller.

Generar ejecutable de servicio en Visual Basic .Net

Generaremos el ejecutable del servicio para poder instalarlo postieriormente, para ello en el IDE de Visual Basic .Net pulsaremos en el menú "Generar" - "Generar AjpdSoftServicioEncriptarCarpeta":

Si no hay errores de compilación VB.Net habrá creado el fichero ejecutable de nuestro servicio Windows en la carpeta bin del proyecto:

Crearemos el fichero de configuración INI para indicar la carpeta a encritar, para ello abriremos el notepad (bloc de notas) de Windows o cualquier otro editor de texto plano y escribiremos el siguiente contenido:

[Configuración]
Carpeta=C:/encriptar

Guardaremos el fichero con el nombre "configuracion.ini" en la misma carpeta que el ejecutable del servicio:

Copiaremos el ejecutable AjpdSoftServicioEncriptarCarpeta.exe y el fichero configuracion.ini a una carpeta de la unidad C para facilitar la instalación del servicio (para evitar rutas largas). Por ejemplo los copiaremos a la carpeta:

C:/ServicioEncriptar

Instalar y desinstalar un servicio de Windows

Instalar servicio de Windows desarrollado con VB.Net

Para instalar el servicio desarrollado anteriormente con VB.Net usaremos la herramienta que incorpora .Net Framework llamada InstallUtil, dicha herramienta suele estar ubicada en:

C:/Windows/Microsoft.NET/Framework/v.xxxxx/InstallUtil.exe

donde v.xxxxx es la versión de .Net Framework que tengamos instalada en el equipo.

Abriremos una ventana de MS-DOS de la línea de comandos como administrador, para ello pulsaremos en el botón "Iniciar" - "Accesorios", sobre "Símbolo del sistema" pulsaremos con el botón derecho del ratón y seleccionaremos "Ejecutar como administrador":

Instalar servicio de Windows desarrollado con VB.Net

Desde la línea de comandos accederemos a la carpeta donde se encuentra el fichero InstallUtil.exe, con el comando "cd":

cd c:/Windows/Microsoft.NET/Framework/v4.0.30319

Para instalar el servicio desarrollado ejecutaremos el siguiente comando:

installutil C:/ServicioEncriptar/AjpdSoftServicioEncriptarCarpeta.exe

Si todo es correcto devolverá:

La fase de confirmación finalizó correctamente.
La instalación con transacciones ha finalizado.

A continuación el listado de los mensajes devueltos tras la instalación del servicio de Windows por InstallUtil:

cd c:/Windows/Microsoft.NET/Framework/v4.0.30319
installutil C:/ServicioEncriptar/AjpdSoftServicioEncriptarCarpeta.exe
Utilidad de instalación de Microsoft (R) .NET Framework, versión 4.0.30319.1
(C) Microsoft Corporation. Reservados todos los derechos.
Ejecutando una instalación de transacción.
Iniciando la fase de instalación dentro de la instalación.
Consulte el contenido del archivo de registro sobre el progreso del ensamblado C:/ServicioEncriptar/AjpdSoftServicioEncriptarCarpeta.exe.
El archivo está ubicado en C:/ServicioEncriptar/AjpdSoftServicioEncriptarCarpeta.InstallLog.
Instalando ensamblado 'C:/ServicioEncriptar/AjpdSoftServicioEncriptarCarpeta.exe'.
Los parámetros afectados son:
logtoconsole =
logfile = C:/ServicioEncriptar/AjpdSoftServicioEncriptarCarpeta.InstallLog
assemblypath = C:/ServicioEncriptar/AjpdSoftServicioEncriptarCarpeta.exe
Instalando el servicio AjpdSoftEncriptarFicheros...
El servicio AjpdSoftEncriptarFicheros se ha instalado correctamente.
Creando el origen de EventLog AjpdSoftEncriptarFicheros en el registro Application...
La fase de instalación finalizó correctamente y la fase de confirmación está empezando.
Consulte el contenido del archivo de registro sobre el progreso del ensamblado C:/ServicioEncriptar/AjpdSoftServicioEncriptarCarpeta.exe.
El archivo está ubicado en C:/ServicioEncriptar/AjpdSoftServicioEncriptarCarpeta.InstallLog.
Confirmando ensamblado 'C:/ServicioEncriptar/AjpdSoftServicioEncriptarCarpeta.exe'.
Los parámetros afectados son:
logtoconsole =
logfile = C:/ServicioEncriptar/AjpdSoftServicioEncriptarCarpeta.InstallLog
assemblypath = C:/ServicioEncriptar/AjpdSoftServicioEncriptarCarpeta.exe
La fase de confirmación finalizó correctamente.
La instalación con transacciones ha finalizado.

Si todo es correcto podremos consultar el servicio en el "Panel de Control" - "Herramientas administrativas" - "Servicios":

Nos aparecerá un nuevo servicio con el nombre "AjpdSoft Encriptar Ficheros", inicialmente en estado detenido. Haciendo doble clic sobre él podremos ver las propiedades:

El nombre del servicio será: AjpdSoftEncriptarFicheros, el nombre para mostrar: "AjpdSoft Encritpar Ficheros", la descripción: "Encripta los ficheros de la carpeta especificada", el tipo de inicio "Automático". Pulsaremos "Iniciar" para activar la aplicación de servicio y así poder probarlo:

Desinstalar servicio de Windows

Si queremos desinstalar el servicio ejecutaremos el siguiente comando:

installutil "C:/ServicioEncriptar/AjpdSoftServicioEncriptarCarpeta.exe" /u

A continuación el listado de los mensajes devueltos tras la desinstalación del servicio de Windows por InstallUtil:

installutil C:/ServicioEncriptar/AjpdSoftServicioEncriptarCarpeta.exe /u
Utilidad de instalación de Microsoft (R) .NET Framework, versión 4.0.30319.1
(C) Microsoft Corporation. Reservados todos los derechos.
Iniciando la desinstalación.
Consulte el contenido del archivo de registro sobre el progreso del ensamblado C:/ServicioEncriptar/AjpdSoftServicioEncriptarCarpeta.exe.
El archivo está ubicado en C:/ServicioEncriptar/AjpdSoftServicioEncriptarCarpeta.InstallLog.
Desinstalando ensamblado 'C:/ServicioEncriptar/AjpdSoftServicioEncriptarCarpeta.exe'.
Los parámetros afectados son:
logtoconsole =
logfile = C:/ServicioEncriptar/AjpdSoftServicioEncriptarCarpeta.InstallLog
assemblypath = C:/ServicioEncriptar/AjpdSoftServicioEncriptarCarpeta.exe
Quitando el origen de EventLog AjpdSoftEncriptarFicheros.
Se está quitando el servicio AjpdSoftEncriptarFicheros del sistema...
El servicio AjpdSoftEncriptarFicheros se ha quitado correctamente del sistema.
La desinstalación ha finalizado.

Depuración de una aplicación de Servicio de Windows con VB.Net

Si la aplicación de servicio con VB.Net produce algún error no controlado por nosotros, será escrito automáticamente en el visor de eventos de Windows. Desde "Inicio" - "Panel de Control" - "Herramientas administrativas" - "Visor de eventos", en "Registros de Windows" - "Aplicación" podremos ver los posibles errores de nuestro servicio:

Si queremos realizar una depuración más a fondo, por ejemplo para saber cuándo nuestra aplicación de servicio encripta un fichero, deberemos escribir nosotros mismos en el visor de eventos. Para ello añadiremos la siguiente línea donde y cuando queramos que la aplicación escriba en el visor de eventos:

Me.EventLog.WriteEntry("Encriptando fichero...")

Podemos controlar los posibles errores de nuestra aplicación y guardar el error que se pueda producir en el Visor de eventos. Para ello, en el código propenso a producir algún error, añadiríamos:

        Try
            
            ...........

        Catch ex As Exception
            Me.EventLog.WriteEntry("Error al encriptar: " & ex.Message)
        End Try

Por supuesto, otra opción para depurar nuestra aplicación de servicio es escribir los eventos que queramos registrar en un fichero de log (fichero de texto plano). De esta forma no necesitaremos escribir en el Visor de eventos y será más sencillo consultar y depurar posibles errores. Un procedimiento para escribir en un fichero de log:

    Private Sub escribirLog(texto As String)
        Dim fichero As New System.IO.StreamWriter("c:\encriptar.log", True)
        fichero.WriteLine(Now & Chr(9) & texto)
        fichero.Close()
    End Sub

Un ejemplo de uso de este procedimiento:

escribirLog("Leyendo carpeta a cifrar de fichero INI")

Cómo reaccionar a los sucesos de apagado y energía en nuestro servicio VB.Net

La mayoría de las aplicaciones de servicio suelen disponer de código de limpieza en sus métodos OnStop y OnPause para que el servicio no consuma recursos cuando no se encuentre en ejecución. En algunos casos, será conveniente ejecutar código especial cuando se apague el sistema o cuando el sistema entre en modo suspensión u otro sucesos relacionado con la alimentación de energía.

Por ejemplo, para ejecutar código cuando se apague el sistema realizaremos los siguientes pasos:

1. Pulsaremos con el botón derecho del ratón sobre el diseñador del servicio y seleccionaremos "Propiedades":

Cómo reaccionar a los sucesos de apagado y energía en nuestro servicio VB.Net

2. Cambiaremos el valor de la propiedad "OnShutdown" a True en la ventana de propiedades del servicio:

3. Añadiremos el siguiente procedimiento para cuando se produzca el evento de apagado del sistema "OnShutdown", en este procedimiento pondremos el código que queramos que se ejecute cuando se vaya a apagar el equipo:

    Protected Overrides Sub OnShutdown()
        cambioFicheroCarpeta.EnableRaisingEvents = False
        escribirLog("El equipo se está apagando")
    End Sub

De la misma forma podremos activar la propiedad "CanHandlePowerEvent" del servicio a True y usaremos el procedimiento "OnPwerEvent" como se indica a continuación:

    Protected Overrides Function OnPowerEvent(powerStatus As  _
                 System.ServiceProcess.PowerBroadcastStatus) As Boolean
        Select Case powerStatus
            Case ServiceProcess.PowerBroadcastStatus.Suspend
                escribirLog("El equipo se está suspendiendo")
            Case ServiceProcess.PowerBroadcastStatus.ResumeSuspend
                escribirLog("El equipo se está saliendo del modo suspensión")
            Case ServiceProcess.PowerBroadcastStatus.BatteryLow
                escribirLog("El equipo tiene la batería baja")
        End Select
        Return True
    End Function

Anexo

Código fuente o source code del servicio de ejemplo de este artículo

Public Class EncriptarCarpeta

    Dim clavesCifrado() As Byte = {234, 125, 22, 6, 54, 45, 254}
    Dim extensionFicherosTMP As String = ".###"

    Protected Overrides Sub OnShutdown()
        cambioFicheroCarpeta.EnableRaisingEvents = False
        escribirLog("El equipo se está apagando")
    End Sub

    Protected Overrides Function OnPowerEvent(powerStatus As  _
                 System.ServiceProcess.PowerBroadcastStatus) As Boolean
        Select Case powerStatus
            Case ServiceProcess.PowerBroadcastStatus.Suspend
                escribirLog("El equipo se está suspendiendo")
            Case ServiceProcess.PowerBroadcastStatus.ResumeSuspend
                escribirLog("El equipo se está saliendo del modo suspensión")
            Case ServiceProcess.PowerBroadcastStatus.BatteryLow
                escribirLog("El equipo tiene la batería baja")
        End Select
        Return True
    End Function

    Private Sub escribirLog(texto As String)
        Dim fichero As New System.IO.StreamWriter("c:\encriptar.log", True)
        fichero.WriteLine(Now & Chr(9) & texto)
        fichero.Close()
    End Sub

    Protected Overrides Sub OnStart(ByVal args() As String)
        Dim carpetaCifrar As String

        escribirLog("Leyendo carpeta a cifrar de fichero INI")

        'Leemos la carpeta a cifrar del fichero INI de configuración
        Dim objFicherosINI As New LeerEscribirFicherosINI(
              System.IO.Path.Combine(System.AppDomain.CurrentDomain.BaseDirectory,
                  "configuracion.ini"))
        carpetaCifrar = objFicherosINI.GetString("Configuración", "Carpeta",
              System.AppDomain.CurrentDomain.BaseDirectory)

        escribirLog("Carpeta a cifrar: " & carpetaCifrar)

        'Comprobamos que el directorio a encriptar existe
        'Si no existe lo creamos
        If Not System.IO.Directory.Exists(carpetaCifrar) Then
            System.IO.Directory.CreateDirectory(carpetaCifrar)
            escribirLog("Carpeta a cifrar no existente, se ha creado")
        End If

        'Activamos la recepción de sucesos de archivos
        cambioFicheroCarpeta.Path = carpetaCifrar
        cambioFicheroCarpeta.EnableRaisingEvents = True
        escribirLog("Activada la recepción de sucesos de archivos")
    End Sub

    Protected Overrides Sub OnStop()
        'Detenemos la recepción de sucesos de archivos
        cambioFicheroCarpeta.EnableRaisingEvents = False

        escribirLog("Detenida la recepción de sucesos de archivos")
    End Sub

    Private Sub cambioFicheroCarpeta_Created(sender As System.Object, _
            e As System.IO.FileSystemEventArgs) _
            Handles cambioFicheroCarpeta.Created
        Dim carpetaCifrar As String

        escribirLog("Obtenemos carpeta a cifrar para activar el monitor de cambios")

        'Leemos la carpeta a cifrar del fichero INI de configuración
        Dim objFicherosINI As New LeerEscribirFicherosINI(
              System.IO.Path.Combine(System.AppDomain.CurrentDomain.BaseDirectory,
                  "configuracion.ini"))
        carpetaCifrar = objFicherosINI.GetString("Configuración", "Carpeta",
              System.AppDomain.CurrentDomain.BaseDirectory)
        If System.IO.Path.GetExtension(carpetaCifrar) <> extensionFicherosTMP Then
            encritarFicheros(carpetaCifrar, clavesCifrado)
        End If
    End Sub

    Private Sub encritarFicheros(ByVal nombreFichero As String, ByVal clavesCifrado() As Byte)
        Me.EventLog.WriteEntry("Encriptando fichero: " & nombreFichero)

        Try
            escribirLog("Encriptando fichero " & nombreFichero)
            'tamaño de cada bloque de entrada, el tamaño para descrifrar deberá ser igual
            Const tamanoBloque = 8192
            'nombre del fichero temporal que se creará para el cifrado
            Dim ficheroTemporal As String = nombreFichero & extensionFicherosTMP
            'abrimos el archivo origen como una secuencia binaria de entrada
            Dim entradaStr As New System.IO.FileStream(nombreFichero, IO.FileMode.Open)
            'abrimos el archivo temporal de salida como una secuencia binaria de entrada
            Dim salidaStr As New System.IO.FileStream(ficheroTemporal, IO.FileMode.Create)
            'determinar el número de bytes que se desean leer
            Dim tamanoBytes As Long = entradaStr.Length
            'preparar un búfer de entrada
            Dim buffer(tamanoBloque - 1) As Byte
            'mientras que haya bytes que leer
            Do While tamanoBytes > 0
                'lectura máxima de 8kb por bloque
                Dim bytesLeer As Long = Math.Min(tamanoBloque, tamanoBytes)
                'leer dentro del búfer de entrada
                entradaStr.Read(buffer, 0, bytesLeer)
                'cifrar este búfer
                encritarArray(buffer, clavesCifrado)
                'enviar la salida a un archivo temporal
                salidaStr.Write(buffer, 0, bytesLeer)
                tamanoBytes -= bytesLeer
            Loop
            'cerrar las dos secuencias
            entradaStr.Close()
            salidaStr.Close()
            'eliminar el archivo de origen
            System.IO.File.Delete(nombreFichero)
            'renombrar el archivo temporal como el original
            System.IO.File.Move(ficheroTemporal, nombreFichero)

            escribirLog("Encriptado fichero " & nombreFichero)
            Me.EventLog.WriteEntry("Encriptado fichero: " & nombreFichero)
        Catch ex As Exception
            Me.EventLog.WriteEntry("Error al encriptar: " & ex.Message)
            escribirLog("Error al encriptar fichero " & nombreFichero & " " & ex.Message)
        End Try
    End Sub

    'Cifrar con xor una matriz de bytes
    Sub encritarArray(ByVal buffer() As Byte, ByVal pwBytes() As Byte)
        'índice que apunta al búfer
        Dim indice As Integer
        'índice que apunta a la matriz de contraseñas
        Dim i As Integer
        'valor máximo de i
        Dim maximo As Integer = pwBytes.Length
        For indice = 0 To buffer.Length - 1
            'hacer un XOR de cada elemento contenido en el búfer con
            'el correspondiente elemento de contraseña
            buffer(indice) = buffer(indice) Xor pwBytes(i)
            'comprobar que el índice corresponde siempre al rango válido
            i = (i + 1) Mod maximo
        Next
    End Sub
End Class

Créditos

Artículo realizado íntegramente por Alonsojpd miembro fundador del Proyecto AjpdSoft.

Artículo en inglés.

4/14/2012